configure.ac

### Configuration

dnl Old versions of Autoconf appear to fail
AC_PREREQ([2.63])

dnl tell configure who we are
dnl parameters: package name, version, where to send bugreports
AC_INIT(sac2c, git, info@sac-home.org)

dnl set source directory and scripting directory
AC_CONFIG_SRCDIR([setup])
AC_CONFIG_AUX_DIR([setup/config])

dnl where to find the SAC standard library sources
CHECK_STDLIB([modules/structures/ArrayBasics.xsac])

dnl we use C as our compiler language
AC_LANG(C)

dnl and which files to create
AC_CONFIG_FILES([src/makefiles/config.mkf setup/sac2crc.pre setup/sac2crc.local src/tools/saccc])
AC_CONFIG_HEADER([src/include/config.h])

dnl check for host type
AC_CANONICAL_BUILD
AC_CANONICAL_HOST
AC_CANONICAL_TARGET

dnl if cygwin set IS_CYGWIN
is_cygwin=0
case "$target_os" in
  *cygwin*) is_cygwin=1 ;;
esac
AC_DEFINE_UNQUOTED([IS_CYGWIN], [$is_cygwin],
                   [Set to 1 if target is Cygwin, otherwise 0.])

dnl set OS and ARCH flags
AC_DEFINE_UNQUOTED([OS], ["$target_os"], [OS string])
AC_DEFINE_UNQUOTED([ARCH], ["$target_cpu"], [CPU architecture string])

dnl Enable sac2c compilation with C++
AC_ARG_ENABLE([cplusplus],
              [AS_HELP_STRING([[--enable-cplusplus]],
                               [Use the C++ compiler to compile files produced by sac2c])],
              [enable_cplusplus=$enableval],
              [enable_cplusplus=no])

dnl Check if C compiler and preprocessor are available
dnl we force CFLAGS to be empty, so that it does not default to -g -O2
CFLAGS=" "
AC_PROG_CC_C99
AC_PROG_CPP

dnl Enable system extensions when they are disabled by default
AC_USE_SYSTEM_EXTENSIONS

dnl Find out if we are using GCC/SunC/DECC/"Mac C"
CHECK_COMPILER_VENDOR

dnl Try to enable link time optimizations (LTO)
CHECK_LTO

dnl Check if C compiler supports SIMD syntax
CHECK_SIMD_SYNTAX

dnl Prints the value of a makefile variable.
getmakevar() {
    makefile="$1"
    var="$2"

    make getmakevar -f -  <<EOI
include $makefile

getmakevar:
	@echo \$($var)
EOI
}

dnl Check for SAC back-ends (CHECK_LPEL must appear after CHECK_MT)
CHECK_MT
CHECK_LPEL
CHECK_CUDA
CHECK_SL
CHECK_OMP
dnl enable private heap manager?
CHECK_PHM
CHECK_DISTMEM

dnl check for ranlib
AC_PROG_RANLIB

dnl check for some standard tools
AC_PROG_LN_S
AC_PROG_SED
AC_PROG_FGREP
AC_PROG_INSTALL
AC_PROG_MKDIR_P

dnl find a code beautifier.
CHECK_CODE_BEAUTIFIER

dnl search/check various utilities
CHECK_REQUIRED_TOOL([SORT], [sort])
CHECK_REQUIRED_TOOL([UNIQ], [uniq])
CHECK_REQUIRED_TOOL([M4], [gm4 m4])
CHECK_REQUIRED_TOOL([XSLT], [xsltproc sabcmd])
CHECK_REQUIRED_TOOL([BASH], [bash])

dnl search for dot
CHECK_GRAPHVIZ

dnl check for various environment features
CHECK_PTR_PREFIX
CHECK_CONST_STDERR
AC_CHECK_HEADERS([malloc.h])
AC_CHECK_FUNCS([mkdtemp])
AC_SEARCH_LIBS([sqrt], [m])
AC_CHECK_FUNCS([strtok strrchr])
CHECK_HR_CLOCK

dnl check support for dynamic libraries
AC_CHECK_HEADER([dlfcn.h], [], [AC_MSG_ERROR([dlfcn.h is required.])])
AC_SEARCH_LIBS([dlopen], [dl])
CHECK_DLL_EXT

enable_uuid=no
AC_SEARCH_LIBS([uuid_generate], [uuid], [enable_uuid=yes], [enable_uuid=no])
AC_CHECK_HEADER([uuid/uuid.h], [enable_uuid=yes], [enable_uuid=no])
have_uuid=`if test $enable_uuid = yes; then echo 1; else echo 0; fi`
AC_DEFINE_UNQUOTED([ENABLE_UUID], [$have_uuid],
                   [Define to 1 if libuuid is available, otherwise 0.])
AC_SUBST([ENABLE_UUID], [$enable_uuid])

enable_crypt=no
AC_SEARCH_LIBS([crypt], [crypt], [enable_crypt=yes], [enable_crypt=no])
AC_CHECK_HEADER([crypt.h], [enable_crypt=yes], [enable_crypt=no])
have_crypt=`if test $enable_crypt = yes; then echo 1; else echo 0; fi`
AC_DEFINE_UNQUOTED([ENABLE_HASH], [$have_crypt],
                   [Define to 1 if libcrypt is available, otherwise 0.])
AC_SUBST([ENABLE_HASH], [$enable_crypt])

dnl set rtspec flag
enable_rtspec=no
if test x"$ac_cv_search_dlopen" != xno -a x"$enable_mt" = xyes ; then
  if test x"$enable_uuid" != xno -o x"$enable_crypt" != xno ; then
    enable_rtspec=yes
  fi
fi

AC_CHECK_LIB(polylib64,DomainIntersection)
AC_SUBST(POLYLIBINCLUDE,["$POLYLIBINCLUDE -I/usr/include/polylib -I/usr/local/include/polylib "])

dnl canonicalize dlopen_libs
case $ac_cv_search_dlopen in
  no | none*) dlopen_libs= ;;
  * ) dlopen_libs=$ac_cv_search_dlopen ;;
esac
have_rtspec=`if test $enable_rtspec = yes; then echo 1; else echo 0; fi`
AC_DEFINE_UNQUOTED([ENABLE_RTSPEC], [$have_rtspec],
                   [Define to 1 if runtime specialization is enabled, otherwise 0.])
AC_SUBST([ENABLE_RTSPEC], [$enable_rtspec])

dnl Check which GCC warning options are available and
dnl add them later to MKCCFLAGS and PDCCFLAGS
gcc_options=
if test "$GCC" = yes ; then
  CHECK_CC_OPTION([-Wall], [gcc_options])
  CHECK_CC_OPTION([-Wextra], [gcc_options])
  CHECK_CC_OPTION([-Wstrict-prototypes], [gcc_options])
  CHECK_CC_OPTION([-Wno-unused-parameter], [gcc_options])
  CHECK_CC_OPTION([-Wno-unused-but-set-variable], [gcc_options])
fi

gcc_native=
if test "$GCC" = yes ; then
  CHECK_CC_OPTION([-march=native], [gcc_native])
  CHECK_CC_OPTION([-mtune=native], [gcc_native])
fi

dnl
dnl test for compiler flags for sac2crc
dnl

dnl test for compiler flags for sac2crc
AC_MSG_CHECKING([sac2crc compiler flags])
if [ test "$GCC" = yes ]; then
  AC_SUBST(OPT_O0, [""])
  AC_SUBST(OPT_O1, [-O1])
  AC_SUBST(OPT_O2, [-O2])
  AC_SUBST(OPT_O3, [-O3])
  AC_SUBST(OPT_g, [-g])
  AC_SUBST(RCCCFLAGS, ["-Wall -Wno-unused -fno-builtin $flags_lto"])
  AC_SUBST(MKCCFLAGS, ["$gcc_options $gcc_native -pedantic -g $flags_lto"])
  AC_SUBST(PDCCFLAGS, ["$gcc_options $gcc_native -pedantic -g -O3 $flags_lto"])
  if [ test "$IS_CYGWIN" = yes ]; then
    AC_SUBST(GENPIC, ["-DPIC"])
  else
    AC_SUBST(GENPIC, ["-fPIC -DPIC"])
  fi
  AC_SUBST(DEPSFLAG, ["-M"])
  AC_SUBST(CPPFILE, ["$CPP -C -x c"])
  AC_SUBST(CPP, ["$CPP -P -x c"])
  AC_MSG_RESULT([gcc settings])
elif [ test "$SUNC" = yes ]; then
  AC_SUBST(OPT_O0, [""])
  AC_SUBST(OPT_O1, [-xO2])
  AC_SUBST(OPT_O2, [-xO4])
  AC_SUBST(OPT_O3, [-xO5])
  AC_SUBST(OPT_g, [-g])
  AC_SUBST(RCCCFLAGS, ["-dalign -fsimple -xsafe=mem"])
  AC_SUBST(MKCCFLAGS, ["-erroff=E_CAST_DOESNT_YIELD_LVALUE -g"])
  AC_SUBST(PDCCFLAGS, ["-erroff=E_CAST_DOESNT_YIELD_LVALUE -g -xO4 -KPIC"])
  AC_SUBST(GENPIC, ["-KPIC"])
  AC_SUBST(DEPSFLAG, ["-xM"])
  AC_SUBST(CPPFILE, ["$CPP -C -x c"])
  AC_SUBST(CPP, ["$CPP -P -x c"])
  AC_MSG_RESULT([Sun cc settings])
elif [ test "$DECC" = yes ]; then
  AC_SUBST(OPT_O0, [""])
  AC_SUBST(OPT_O1, [-O1])
  AC_SUBST(OPT_O2, [-O2])
  AC_SUBST(OPT_O3, [-O3])
  AC_SUBST(OPT_g, [-g])
  AC_SUBST(RCCCFLAGS, [""])
  AC_SUBST(MKCCFLAGS, ["-g"])
  AC_SUBST(PDCCFLAGS, ["-g3"])
  AC_SUBST(GENPIC, [""])
  AC_SUBST(DEPSFLAG, ["-M"])
  AC_SUBST(CPPFILE, ["$CPP -C -x c"])
  AC_SUBST(CPP, ["$CPP -P -x c"])
  AC_MSG_RESULT([Compaq/DEC cc settings])
elif [ test "$MACC" = yes ]; then
  AC_SUBST(OPT_O0, [""])
  AC_SUBST(OPT_O1, [-O1])
  AC_SUBST(OPT_O2, [-O2])
  AC_SUBST(OPT_O3, [-O3])
  AC_SUBST(OPT_g, [-g])
  AC_SUBST(RCCCFLAGS, ["-Wall -Wno-unused -fno-builtin"])
  AC_SUBST(MKCCFLAGS, ["-Wall -g"])
  AC_SUBST(PDCCFLAGS, [""])
  AC_SUBST(GENPIC, [""])
  AC_SUBST(DEPSFLAG, ["-M"])
  AC_SUBST(CPPFILE, ["$CPP -C -x c"])
  AC_SUBST(CPP, ["$CPP -P -x c"])
  AC_MSG_RESULT([Apple cc settings])
else
  AC_SUBST(OPT_O0, [""])
  AC_SUBST(OPT_O1, [""])
  AC_SUBST(OPT_O2, [""])
  AC_SUBST(OPT_O3, [""])
  AC_SUBST(OPT_g, [""])
  AC_SUBST(RCCCFLAGS, [""])
  AC_SUBST(MKCCFLAGS, [""])
  AC_SUBST(PDCCFLAGS, [""])
  AC_SUBST(GENPIC, [""])
  AC_SUBST(DEPSFLAG, ["-M"])
  AC_SUBST(CPPFILE, ["$CPP -C"])
  AC_SUBST(CPP, ["$CPP -P"])
  AC_MSG_RESULT([none found])
fi
AC_SUBST(CCMT_PTH_LINK, ["$PTHREAD_LIBS"])
AC_SUBST(CCMT_PTH_CFLAGS, ["$PTHREAD_CFLAGS"])
AC_SUBST(CCDLLINK, ["$dlopen_libs $flags_lto"])

dnl This is a special case for building sac2c with c++ compiler.
if [[ "$GXX" = yes -a "$enable_cplusplus" = yes ]]; then
  AC_SUBST(SAC2C_CC, ["g++"])
  AC_SUBST(OPT_O0, [""])
  AC_SUBST(OPT_O1, [-O1])
  AC_SUBST(OPT_O2, [-O2])
  AC_SUBST(OPT_O3, [-O3])
  AC_SUBST(OPT_g, [-g])
  AC_SUBST(RCCCFLAGS, ["-Wall -Wno-unused -fno-builtin"])
  AC_SUBST(SAC2C_MKCCFLAGS, ["-Wno-write-strings -g"])
  AC_SUBST(SAC2C_PDCCFLAGS, ["-Wno-write-strings -g -O3"])
  AC_SUBST(GENPIC, ["-fPIC -DPIC"])
  AC_SUBST(DEPSFLAG, ["-M"])
  AC_SUBST(CPPFILE, ["$CPP -C -x c"])
  AC_SUBST(CPP, ["$CPP -P -x c"])
  AC_MSG_RESULT([gcc settings])
else
  AC_SUBST(SAC2C_CC, ["$CC"])
  AC_SUBST(SAC2C_MKCCFLAGS, ["$MKCCFLAGS"])
  AC_SUBST(SAC2C_PDCCFLAGS, ["$PDCCFLAGS"])
fi

dnl
dnl append platform specific files to sac2crc
dnl

AC_SUBST_FILE([RCMUTC])
AC_SUBST_FILE([RCCUDA])
AC_SUBST_FILE([RCCC])
AC_SUBST_FILE([RCMALLOC])
AC_SUBST_FILE([RCRCM])
AC_SUBST_FILE([RCSUN])
AC_SUBST_FILE([RCX86])
AC_SUBST_FILE([RCALPHA])
AC_SUBST_FILE([RCMAC])
RCMUTC=setup/sac2crc.backend.mutc
RCCUDA=setup/sac2crc.backend.cuda
RCCC=setup/sac2crc.modifiers.cc
RCMALLOC=setup/sac2crc.modifiers.malloc
RCRCM=setup/sac2crc.modifiers.rcm
RCSUN=setup/sac2crc.SUN
RCX86=setup/sac2crc.X86
RCALPHA=setup/sac2crc.ALPHA
RCMAC=setup/sac2crc.MAC

dnl
dnl Append GASNet conduit targets file to sac2crc.
dnl
AC_SUBST_FILE([GASNET_CONDUIT_TARGETS])
GASNET_CONDUIT_TARGETS=./sac2crc.GASNetconduits

dnl
dnl Append GASNet conduit settings file to config.mkf.
dnl
AC_SUBST_FILE([GASNET_CONDUIT_SETTINGS])
GASNET_CONDUIT_SETTINGS=./config.GASNetconduits

dnl
dnl Append rules for building libsacdistmem GASNet object files to build.mkf
dnl
AC_SUBST_FILE([GASNET_CONDUIT_BUILD_OBJECT_FILES])
GASNET_CONDUIT_BUILD_OBJECT_FILES=./build.GASNetconduits

dnl
dnl Append rules for building libsacdistmem GASNet cross variant object files to build.mkf
dnl
AC_SUBST_FILE([GASNET_CONDUIT_BUILD_OBJECT_FILES_CROSS_VARIANT])
GASNET_CONDUIT_BUILD_OBJECT_FILES_CROSS_VARIANT=./build.GASNetconduitsCrossVariant

# generate specific flags for known os
AC_MSG_CHECKING([sac2crc system flags])

OSFLAGS=""
case "$target_os" in
  solaris*)
    OSFLAGS=["-D__EXTENSIONS__ -D_XPG6 -DMUST_INIT_YY -DPIC"]
    LD_DYNAMIC=["-G -dy"]
    LD_PATH=["-L%path% -R%path%"]
    LD_FLAGS="-Wl,-z,nodefs,-z,lazyload"
    AC_MSG_RESULT([solaris settings])
    ;;
  *linux*)
    OSFLAGS=["-fPIC -DPIC -D_POSIX_SOURCE -D_DEFAULT_SOURCE -D_SVID_SOURCE -D_BSD_SOURCE"]
    LD_DYNAMIC=["-shared -Wl,-allow-shlib-undefined -O3 $flags_lto"]
    LD_PATH=["-L%path% -Wl,-rpath,%path%"]
    LD_FLAGS="-Wl,-allow-shlib-undefined $flags_lto"
    AC_MSG_RESULT([linux settings])
    ;;
  *cygwin* | *mingw*)
    OSFLAGS=["-D_POSIX_SOURCE -D_SVID_SOURCE -D_BSD_SOURCE"]
    LD_DYNAMIC=["-dy -shared"]
    LD_PATH=["-L%path% -Wl,-rpath,%path%"]
    LD_FLAGS=""
    AC_MSG_RESULT([cygwin settings])
    ;;
  *osf*)
    OSFLAGS=["-D_OSF_SOURCE"]
    LD_DYNAMIC=[""]
    LD_PATH=["-L%path%"]
    LD_FLAGS=""
    AC_MSG_RESULT([OSF settings])
    ;;
  *darwin*)
    dnl darwin needs some extra flags
    RANLIB="$RANLIB -c"
    OSFLAGS=["-D_DARWIN_C_SOURCE"]
    LD_DYNAMIC=["-undefined suppress -flat_namespace -dynamiclib -install_name '@rpath/%libname%.dylib' "]
    LD_PATH=["-L%path% -Wl,-rpath,%path%"]
    LD_FLAGS=""
    AC_MSG_RESULT([darwin settings])
    ;;
  *bsd*)
    OSFLAGS=["-fPIC -DPIC"]
    LD_DYNAMIC=["-shared -symbolic -Wl,-allow-shlib-undefined $flags_lto"]
    LD_PATH=["-L%path% -Wl,-rpath,%path%"]
    LD_FLAGS=["$flags_lto"]
    AC_MSG_RESULT([BSD settings])
    ;;
  *)
    OSFLAGS=["-fPIC -DPIC -D_POSIX_SOURCE -D_SVID_SOURCE -D_BSD_SOURCE"]
    LD_DYNAMIC=["-dy -shared -Wl,-allow-shlib-undefined"]
    LD_PATH=["-L%path% -Wl,-rpath,%path%"]
    LD_FLAGS="-Wl,-allow-shlib-undefined"
    AC_MSG_RESULT([unknown])
    ;;
esac

AC_SUBST([OS], [$target_os])
AC_SUBST([OSFLAGS])
AC_SUBST([CFLAGS])
AC_SUBST([CPPFLAGS])
AC_SUBST([LDFLAGS])
AC_SUBST([LD_DYNAMIC])
AC_SUBST([LD_PATH])
AC_SUBST([LD_FLAGS])

dnl
dnl static sac2c settings for config.h
dnl

AC_DEFINE([PF_MAXFUN], [100], [set to maximum number of sac functions for profiling])
AC_DEFINE([PF_MAXFUNAP], [100],
           [set to maximum number of sac function applications for profiling])
AC_DEFINE([PF_MAXFUNNAMELEN], [100],
           [set to maximum length of sac function names for profiling])

AC_DEFINE([SAC_PRELUDE_NAME], ["sacprelude"], [Name of the sac prelude module.])
AC_DEFINE( UNUSED, __attribute__((unused)), define macro for unused variables)





if test x"$enable_distmem_gasnet" = xyes; then
  gasnet_conduit_names_print=" (conduits: $gasnet_conduit_names)"
else
  gasnet_conduit_names_print=""
fi

if test x"$enable_distmem" = xyes; then
  distmem_details_print=" (experimental)
*   - GASNet:              $enable_distmem_gasnet$gasnet_conduit_names_print
*   - GPI:                 $enable_distmem_gpi
*   - MPI:                 $enable_distmem_mpi
*   - ARMCI:               $enable_distmem_armci"
else
  distmem_details_print=""
fi

AC_OUTPUT

cat <<EOF
* Configuration done.
*
* Detected OS string:      $target_os
* Detected CPU string:     $target_cpu
*
* Run-time specialization: $enable_rtspec
* Private heap manager:    $enable_phm
* Back-ends:
* - MT/pthread:            $enable_mt
* - MT/LPEL:               $enable_mt_lpel
* - CUDA:                  $enable_cuda
* - OpenMP:                $enable_omp
* - SL:                    $enable_sl
* - Distributed memory:    $enable_distmem$distmem_details_print
* - CC:                    $CC
* - SaC compiler CFLAGS:   $MKCCFLAGS
* - SaC programs CFLAGS:   $RCCCFLAGS
*
EOF