/********************************************************************************
 *
 * Livermoore Loop no 9
 *
 * Integrate Predictors
 * Parallel Algorithm
 *
 * This runs a fair bit slower than the C version, but it's so elegant
 * that I can't resist. This needs a revisit, perhaps after the LIR
 * bug is repaired. 
 *
 ********************************************************************************/

use StdIO: all;
use Array: all;
use String:{tochar};

/* Vector length */
#define N 1001

inline double[.] vecmatmul( double[.] wts, double[.,.] PX) {
  colsx = shape(wts)[0];
  colsy = shape(PX)[1];
  z = genarray([colsy], 0.0d);
  for (colx=0; colx<colsx; colx++) {
    if (0.0 != wts[colx]) { /* Skip iteration if it's an f identity */
      z = z + wts[colx] * PX[colx];
    }
  }
  return(z);
}

/*
 * The superfluous argument i to Loop9 has been added in order to prevent LIR 
 * from moving the Loop1 call from the WL in main.
 */

double Loop9( int i, int n, double[.] wts, double[.,.] PX)
{
  res = sum( vecmatmul( wts, PX));
  return( res);
}

double[.,.] gen2dArray(int h, int w)
{
  A = tod(1 + iota(h*w));
  B = reshape([h, w], A);
  return(B);
}

int main ()
{
  rep = (:int)FibreScanIntArray( );    /* 500000 */
  n = (:int) FibreScanIntArray();      /*   N */
  CO   = (:double)FibreScanDoubleArray( );
  DM22 = (:double)FibreScanDoubleArray( );
  DM23 = (:double)FibreScanDoubleArray( );
  DM24 = (:double)FibreScanDoubleArray( );
  DM25 = (:double) FibreScanDoubleArray( );
  DM26 = (:double)FibreScanDoubleArray( );
  DM27 = (:double) FibreScanDoubleArray( );
  DM28 = (:double) FibreScanDoubleArray( );

  PX  = gen2dArray( 25, N);
  wts = genarray([25], 0.0d);
  wts[2] = 1.0;
  wts[4] = CO;
  wts[5] = CO;
  wts[6] = DM22;
  wts[7] = DM23;
  wts[8] = DM24;
  wts[9] = DM25;
  wts[10] = DM26;
  wts[11] = DM27;
  wts[12] = DM28;

  z = 0.0;
  for( i=0; i<rep; i++) {
    z = z + Loop9( i, N, wts, PX);
  }
  StdIO::show( z);
  return(0);
}